Scripting Academy http://herc.ws/board/blog/29-scripting-academy/ Scripting Academy Syndication Wed, 13 Jan 2016 02:08:24 +0000 haru@dotalux.com (Hercules Board) IP.Blog 60 Disguise Event Script http://herc.ws/board/blog/29/entry-101-disguise-event-script/ Disguise Event Script ( 3 Parts )
Due, to the possibility of this script being removed from Hercules' main repository, I'm going to write a guide for this script. Well, that and I lack the imagination to write up a new script from scratch right now @.@;
Because this post is tremendously long, each part has been wrapped in spoiler tags to help make it easier to follow.

Part 1
Spoiler

Part 2
Spoiler

Part 3
Spoiler
]]> Fri, 28 Nov 2014 06:36:00 +0000 http://herc.ws/board/blog/29/entry-101-disguise-event-script/ Did I help you? Let me know! http://herc.ws/board/blog/29/entry-100-did-i-help-you-let-me-know/ Either that or perhaps it's the scripts I chose. Either way, let me know! I'll try to correct my faults, because if you came here, you obviously wanted to learn as well !]]> Fri, 28 Nov 2014 00:07:00 +0000 http://herc.ws/board/blog/29/entry-100-did-i-help-you-let-me-know/ Custom AtCommand @buff http://herc.ws/board/blog/29/entry-99-custom-atcommand-buff/ Custom AtCommand @buff ( 2 parts )
A custom @command, that will buff the player with preset buffs, have a cast time, cost zeny, have a cooldown time and will unlock more buffs the more they use it!

Part 1
Okay, so now it's time for us to make our first @command using a script. Which means we don't need to modify the src code in any way.

Let's start off by making a floating npc:
-    script    at_buff    -1,{

Now we are going to tell the script to create a custom @command for us, to do so we will be using this command: bindatcmd "command","<NPC object name>::<event label>"{,<group level>,<group level char>,<log>};
So let's add ours under OnInit: and call it @buff. For <NPC_object_name>, we'll be using this command to retrieve that: strnpcinfo(<type>).
Lastly, let's call the event label, OnAtBuff:
OnInit:
    bindatcmd "buff", strnpcinfo(3)+"::OnAtBuff";

Now, let's add our other variables. Let's make this command have a cast time of 5 seconds, cost 10.000z to use, and have a cool-down time of 10 minutes. Let's also set a variable for how many tiers of buffs there are, and what the cap tier is.
For this example we'll use 10 as each increment of a tier, and cap it at 2 additional tiers:
    .cast_time = 5;
    .zeny = 10000;
    .cool_down = 600;
    .tiers = 10;
    .buff_level_limit = 2 * tiers;
    end;

Let's move on to our next step. We'll start by making the OnAtBuff: label:
OnAtBuff:

From here we need to first, preform the check for the cool-down, to see if they've used the command recently. We're going to be using this command for that: gettimetick(<tick type>).
But first we need to use a player_variable to check against, we'll call this variable buff_cool_down:
if (buff_cool_down > gettimetick(2)) {

Now that we got the check out of the way, let' sput a message that says "You cannot use this command for another - X amount of minutes.
To do that, we are going to use this command: dispbottom "<message>";
in combination with this function: Time2Str. What that function will do is convert the cool-down into a readable time for us.
To call the function we'll use this command: callfunc "<function>"{,<argument>,...<argument>};
So let's add it all in:
    dispbottom "You cannot use this command for another: "+ callfunc("Time2Str",buff_cool_down) +"";
    end;
}

Let's continue on now that we took care of that, and create our check to see if they have enough zeny. Again, using dispbottom to let them know they don't have enough zeny:
    if (Zeny < .zeny) {
        dispbottom "It costs "+ .zeny +" zeny to use this command.";
        end;
    }

Now it's time to add the cast time for the command. To do so we need to use this command: progressbar "<color>",<seconds>;
    progressbar "0x00FF00", .cast_time;

Okay, now since things in RO are subject to change at any given time, we need to perform the zeny check once more to make sure they didn't some how store their Zeny away. So let's just copy+paste that again, below the progressbar. Also, another reason for doing it this way, is to not make the player suffer through a loading bar when they initially didn't have enough Zeny. That would just be too curel. Unless you like that sort of thing:
    if (Zeny < .zeny) {
        dispbottom "It costs "+ .zeny +" zeny to use this command.";
        end;
    }

Now, all that's left to do is take away the zeny for payment, and add the buffs as needed. To do that we'll be using switch() to make them cycle through the appropriate buffs. We'll determine that by creating a scope_variable that divides a player_variable by .tiers. We also need to increase the player_variable by 1 after receiving buffs, and check to make sure it isn't above the level limit:
    Zeny -= .zeny;
    .@buffs = at_buff_usuage / .tiers;
    switch( .@buffs ){
        case 20:
            sc_start SC_ASSUMPTIO,300000,5;
	
        case 10:
            sc_start SC_IMPOSITIO,300000,5;
	
        case 0:
            sc_start SC_BLESSING,300000,10;
            sc_start SC_INC_AGI,300000,10;
            ++at_buff_usage;
            if (at_buff_usage > .buff_level_limit) {
                at_buff_usage = .buff_level_limit
            }
    }

Now, all we need to do is, add the cool-down as proof they used the command:
    buff_cool_down = gettimetick(2) + .cool_down;
    end;

Also, since that's the end of the script let's close it off. And when you're done, it should look something like this:
-	script	at_buff	-1,{
OnInit:
    bindatcmd "buff", strnpcinfo(3)+"::OnAtBuff";
    .cast_time = 5;
    .zeny = 10000;
    .cool_down = 600;
    .tiers = 10;
    .buff_level_limit = 2 * .tiers;
    end;

OnAtBuff:
    if (buff_cool_down > gettimetick(2)) {
        dispbottom "You cannot use this command for another: "+ callfunc("Time2Str",buff_cool_down) +"";
        end;
    }
    if (Zeny < .zeny) {
        dispbottom "It costs "+ .zeny +" zeny to use this command.";
        end;
    }
    progressbar "0x00FF00", .cast_time;
    if (Zeny < .zeny) {
        dispbottom "It costs "+ .zeny +" zeny to use this command.";
        end;
    }
    Zeny -= .zeny;
    .@buffs = at_buff_usuage / .tiers;
    switch( .@buffs ){
        case 20:
            sc_start SC_ASSUMPTIO,300000,5;
	
        case 10:
    	    sc_start SC_IMPOSITIO,300000,5;
	
        case 0:
  	    sc_start SC_BLESSING,300000,10;
	    sc_start SC_INC_AGI,300000,10;
	    ++at_buff_usuage;
            if (at_buff_usuage > .buff_level_limit) {
                at_buff_usage = .buff_level_limit;
	    }
    }
    buff_cool_down = gettimetick(2) + .cool_down;
    end;
}
And that's it, you just finished making a custom @buff command that everyone in your server can use.

Part 2
Alright, so here we are going to limit the use of this command to certain maps depending on mapflags that are already set in place on those maps. Additionally, we are going to clean the script up a bit.

So let's start by opening up our script again:
-	script	at_buff	-1,{
OnInit:
    bindatcmd "buff", strnpcinfo(3)+"::OnAtBuff";
    .cast_time = 5;
    .zeny = 10000;
    .cool_down = 600;
    .tiers = 10;
    .buff_level_limit = 2 * .tiers;
    end;

OnAtBuff:
    if (buff_cool_down > gettimetick(2)) {
        dispbottom "You cannot use this command for another: "+ callfunc("Time2Str",buff_cool_down) +"";
        end;
    }
    if (Zeny < .zeny) {
        dispbottom "It costs "+ .zeny +" zeny to use this command.";
        end;
    }
    progressbar "0x00FF00", .cast_time;
    if (Zeny < .zeny) {
        dispbottom "It costs "+ .zeny +" zeny to use this command.";
        end;
    }
    Zeny -= .zeny;
    .@buffs = at_buff_usuage / .tiers;
    switch( .@buffs ){
        case 20:
            sc_start SC_ASSUMPTIO,300000,5;
	
        case 10:
    	    sc_start SC_IMPOSITIO,300000,5;
	
        case 0:
  	    sc_start SC_BLESSING,300000,10;
	    sc_start SC_INC_AGI,300000,10;
	    ++at_buff_usuage;
            if (at_buff_usuage > .buff_level_limit) {
                at_buff_usage = .buff_level_limit;
	    }
    }
    buff_cool_down = gettimetick(2) + .cool_down;
    end;
}

To start with, we are going to be adding a new array under OnInit: called .mapflags. In side the array we will add all the mapflags that we wish to use to limit our commands usage.
For a list of mapflags look here: mapflags.
Now then let's add our flags in to limit use in areas that are PvP, GvG or BattleGrounds:
    setarray .mapflags[0],mf_pvp,
                          mf_pvp_noparty,
	       	          mf_pvp_noguild,
		          mf_gvg,
		          mf_gvg_noparty,
		          mf_gvg_castle,
		          mf_battleground;

With that out of the way let's add a check under our OnAtBuff: label to see if the map the player is on, has any of these mapflags on them. To do that we will be using this loop command: for (<variable initialization>; <condition>; <variable update>) <statement>;
in combination with this command to perform the actual check: getmapflag("<map name>",<flag>).
To get the mapname of the player we will use this command: strcharinfo(<type>).
So let's make our loop, and also let the player know that they can't use the command on PvP, GvG and BattleGround maps. This should be no problem for you now, after the few scripts we've done:
   for (.@i = 0; .@i < getarraysize(.mapflags[0]); .@i++) {
  	    if (getmapflag( strcharinfo(3), .mapflags[.@i] )) {
		    dispbottom "This command is disabled on PVP, GVG and BattleGround maps.";
		    end;
	    }
    }

Alright, now we need to do the clean up portion of this edit. To do this, we'll be making a new label at the bottom of our script. We'll call it OnZenyCheck:. Underneath this label we'll add our zeny check we already have in the script. Lastly, beneath the check we will be adding this command: return {<value>}; without the value:
    if (Zeny < .zeny) {
        dispbottom "It costs "+ .zeny +" zeny to use this command.";
        end;
    }
    return;

Now the last ting you need to is replace the other Zeny checks with this command: callsub <label>{,<argument>,...<argument>}; For this we won't be using any arguments, we are just going to call the label, OnZenyCheck
What this will do is instead of typing out the check twice, we simply type it once, and make the script call the check and return to the point of it's execution.
So let's add them in:
callsub OnZenyCheck;

Now, we are done. Your script should look something like this:
-	script	at_buff	-1,{
OnInit:
    bindatcmd "buff", strnpcinfo(3)+"::OnAtBuff";
    .cast_time = 5;
    .zeny = 10000;
    .cool_down = 600;
    .tiers = 10;
    .buff_level_limit = 2 * .tiers;
    setarray .mapflags[0],mf_pvp,
                          mf_pvp_noparty,
		          mf_pvp_noguild,
		          mf_gvg,
		          mf_gvg_noparty,
		          mf_gvg_castle,
		          mf_battleground;
    end;

OnAtBuff:
    for (.@i = 0; .@i < getarraysize(.mapflags[0]); .@i++) {
        if (getmapflag( strcharinfo(3), .mapflags[.@i] )) {
            dispbottom "This command is disabled on PVP, GVG and BattleGround maps.";
            end;
        }
    }
    if (buff_cool_down > gettimetick(2)) {
        dispbottom "You cannot use this command for another: "+ callfunc("Time2Str",buff_cool_down) +"";
        end;
    }
    callsub OnZenyCheck;
    progressbar "0x00FF00", .cast_time;
    callsub OnZenyCheck;
    Zeny -= .zeny;
    .@buffs = at_buff_usuage / .tiers;
    switch( .@buffs ){
	    case 20:
	        sc_start SC_ASSUMPTIO,300000,5;
	
	    case 10:
	        sc_start SC_IMPOSITIO,300000,5;
	
	    case 0:
	        sc_start SC_BLESSING,300000,10;
	        sc_start SC_INC_AGI,300000,10;
	        ++at_buff_usuage;
	        if (at_buff_usage > .buff_level_limit) {
	            at_buff_usuable = .buff_level_limit;
	        }
    }
    buff_cool_down = gettimetick(2) + .cool_down;
    end;

OnZenyCheck:
    if (Zeny < .zeny) {
        dispbottom "It costs "+ .zeny +" zeny to use this command.";
        end;
    }
    return;
}
And that's it, we're done with this script.]]> Thu, 27 Nov 2014 10:42:00 +0000 http://herc.ws/board/blog/29/entry-99-custom-atcommand-buff/ Bounty Hunting PvP Script http://herc.ws/board/blog/29/entry-98-bounty-hunting-pvp-script/ Bounty Hunting PvP Script ( 2 Parts )
An intermediate level PvP script. This script is intended to help improve your scripting abilities, while also making you feel more comfortable about PvP scripts.

Part 1
Alright, before we begin I'm assuming you already completed the Basic PvP Script. If not, you will need to do so to follow along.

Otherwise let's continue, by first creating a floating npc, followed by the OnInit: label:
-    script    bounty_script    -1,{
OnInit:

Now that we got rid of the easy part, let's add some configurations to our script.
We'll start by setting up the following 2 variables:
    .bounty = 10000;
    .wanted_increments = 1000000;
    end;

Those will be used later when we determine what happens when a player is killed in PvP combat. So to continue on, we are going to be adding the OnPCKillEvent: label followed by a check to see if the person who died, is also the killer and if so, end the script.
To do that we'll need to use getcharid(3), as this will return the account id:
OnPCKillEvent:
    if (killedrid == getcharid(3)) {
        end;
    }

Now, this is a bit different than normal, because right now the script is attached to the killer. But we want to make changes to the killed person first, so let's attach the script to that person:
attachrid(killedrid);

Alright, now we need to set 2 variables. The first being .@zeny to the player's current bounty regardless of whether or not he had one.
To do this, we need to use the command: getcharid(0); as the element of an array.
It should look like this:
    .@zeny = .bounty[getcharid(0)];

Now we just need to set the player's bounty to 0 since he was killed. So let's do that:
    .bounty[getcharid(0)] = 0;

Now the last thing we are going to do with this player is save their name into a scope-string variable for later use, let's call it .@name$, and remember the command to get their name is: strcharinfo(<type>);
    .@name$ = strcharinfo(0);

Now that we are done making changes to the killed player, let's attach the script back to the killer:
attachrid(killerrid);

Here we are going to do 2 things. The first is, we are going to increase the killer's Zeny by the variable .@zeny which we got from the killed player. The second is, we are going to increase the killer's bounty by the variable .bounty.
So let's do that:
    Zeny += .@zeny;
    .bounty[getcharid(0)] += .bounty;

See, that wasn't too hard. Finally, we are going to announce that the player has killed the other player, as well as show what his bounty level is. This will be determined by dividing his bounty by the .wanted_increments variable we made earlier in the script. Also, we will be using a (? :) condition to properly announce whether or not the killer is male or female. Along with what the player's bounty is so others can hunt them down. And lastly, announce it to everyone, in blue.
Let's do it:
    announce "["+ strcharinfo(0) +"] has killed ["+ .@name$ +"]. "+ (Sex?"He":"She") +" has a bounty of: "+ .bounty[getcharid(0)] +"") +" zeny! [ WANTED LEVEL "+ ( .bounty[getcharid(0)] / .wanted_increments ) +" ]",bc_blue|bc_all;

Alright. That's it, when you're all done it should look something like this:
-	script	bounty_script	-1,{
OnInit:
    .bounty = 10000;
    .wanted_increments = 100000;
    end;

OnPCKillEvent:
    if (killedrid == getcharid(3)) {
	end;
    }
    attachrid(killedrid);
	.@zeny = .bounty[getcharid(0)];
	.bounty[getcharid(0)] = 0;
	.@name$ = strcharinfo(0);
		
    attachrid(killerrid);
	Zeny += .@zeny;
	.bounty[getcharid(0)] += .bounty;
	announce "["+ strcharinfo(0) +"] has killed ["+ .@name$ +"]. "+ (Sex?"He":"She") +" has a bounty of: "+ .bounty[getcharid(0)] +" zeny! [ WANTED LEVEL "+ ( .bounty[getcharid(0)] / .wanted_increments ) +" ]",bc_blue|bc_all;
    end;
}
And that's it for now. We'll make some more improvements, as well as add more features in part 2.

Part 2
Okay, let's just jump straight into this one.

Let's open up the script from last time:
-	script	bounty_script	-1,{
OnInit:
    .bounty = 10000;
    .wanted_increments = 100000;
    end;

OnPCKillEvent:
    if (killedrid == getcharid(3)) {
	end;
    }
    attachrid(killedrid);
	.@zeny = .bounty[getcharid(0)];
	.bounty[getcharid(0)] = 0;
	.@name$ = strcharinfo(0);
		
    attachrid(killerrid);
	Zeny += .@zeny;
	.bounty[getcharid(0)] += .bounty;
	announce "["+ strcharinfo(0) +"] has killed ["+ .@name$ +"]. "+ (Sex?"He":"She") +" has a bounty of: "+ .bounty[getcharid(0)] +" zeny! [ WANTED LEVEL "+ ( .bounty[getcharid(0)] / .wanted_increments ) +" ]",bc_blue|bc_all;
    end;
}

Now, the additions we're going to put in here are peretty simple. We are going to add 3 things in:
1) A check so that this script only works on certain maps.
2) Whether or not to warp the player to their SavePoint upon death.
3) Whether or not player's lose zeny when they die.
So let's add those variables into OnInit:
.mapname$ = "pvp_y_2-1";
.warp_death = 1;
.zeny_loss = .bounty;

So above, we chose our map that it is enabled on, also said yes players get warped out upon dying and the .zeny_loss is set to the bounty players gain per kill. Seems easy enough, now the next step is to add a check to see if the killer is on the same map as what we specified.
So let's add the check directly under OnPCKillEvent: using strcharinfo(3):
if (strcharinfo(3) != .mapname$) {
    end;
}

Took care of that. And now it won't cause any problems down the line.
Alright, we're almost done. Just need to add a few more checks regarding the zeny_loss variable. Let's knock those out. We are going to check if .zeny_loss is enabled.
So let's do that:
if (.zeny_loss) {

Okay, now we need to add another check inside of that one. This time, we are going to check if the player has Zeny less-than how much we are going to take away. If they do, we are going to take away the remaining zeny from them. If they happen to have more, we'll take away just what we need to.
So let's do that:
    if (Zeny < .zeny_loss) {
        Zeny -= Zeny;
    } else {
        Zeny -= .zeny_loss;
    }
}

Alright, last thing we need to do is add the check to see if .warp_death is enabled, and if so, warp the dead player out. So we'll add that right before we end the script.
To do that, we need to use this command: warp "<map name>",<x>,<y>;
So let's add it in:
if (warp_death) {
    warp "SavePoint",0,0;
}

Now we are finished. Your script should look something like this:
-	script	bounty_script	-1,{
OnInit:
    .bounty = 10000;
    .wanted_increments = 100000;
    .mapname$ = "pvp_y_2-1";
    .warp_death = 1;
    .zeny_loss = .bounty;
    end;

OnPCKillEvent:
    if (strcharinfo(3) != .mapname$ && .mapname$ != "") {
        end;
    }
    if (killedrid == getcharid(3)) {
	end;
    }
    attachrid(killedrid);
	.@zeny = getd(".bounty"+ getcharid(0) +"");
	setd ".bounty"+ getcharid(0) +"", 0;
	.@name$ = strcharinfo(0);
	if (.zeny_loss) {
            if (Zeny < .zeny_loss) {
                Zeny -= Zeny;
            } else {
                Zeny -= .zeny_loss;
            }
        }
    attachrid(killerrid);
	Zeny += .@zeny;
	setd ".bounty"+ getcharid(0) +"", getd(".bounty"+ getcharid(0) +"") + .bounty;
	announce "["+ strcharinfo(0) +"] has killed ["+ .@name$ +"]. "+ (Sex?"He":"She") +" has a bounty of: "+ getd(".bounty"+ getcharid(0) +"") +" zeny! [ WANTED LEVEL "+ ( getd(".bounty"+ getcharid(0) +"") / .wanted_increments ) +" ]",bc_blue|bc_all;
    if (.warp_death) {
        warp "SavePoint",0,0;
    }    
    end;
}
And that's it. We just finished making a Bounty Hunting PvP script, that doesn't involve having to do anything but kill. This should inspire people to want to pvp now.]]> Wed, 26 Nov 2014 02:17:00 +0000 http://herc.ws/board/blog/29/entry-98-bounty-hunting-pvp-script/ <![CDATA[Intermediate Healer & Buffer Script]]> http://herc.ws/board/blog/29/entry-97-intermediate-healer-buffer-script/ Intermediate Healer & Buffer Script ( 2 parts )
An intermediate version of the Basic Healer & Buffer Script.

Part 1

Okay let's start by opening up the final version of our Basic Healer & Buffer Script.
prontera,150,180,4	script	Healer	4_F_ARUNA_POP,{
mes "[^0000FF Healer ^000000]";
mes "Would you like me to heal you?";
mes "^FF0000 *Note - It costs "+ .heal_price +" zeny to get healed.* ^000000";
mes "^FF0000 *Note - AGI-UP + BLESSING Level 10 costs "+ .buff_price +" zeny.* ^000000";
switch( select("Yes, heal me.", "I want buffs", "No thank you") ) {
	case 1:
		if (Zeny < .heal_price) {
			mes "I'm sorry, but you don't have enough zeny.";
			close;
		}
		Zeny -= .heal_price;
		percentheal 100,100;
		break;
	
	case 2:
		if (Zeny < .buff_price) {
			mes "I'm sorry, but you don't have enough zeny.";
			close;
		}
		Zeny -= .buff_price;
		sc_start SC_BLESSING,300000,10;
		sc_start SC_INC_AGI,300000,10;
		break;
}
close;

OnInit:
    .heal_price = 1000;
    .buff_price = 5000;
    end;
}

So what we're going to do here is edit our script quite a bit. but firstly we are going to make the zeny price for healing / buffing optional. To do that is simple. We just need to put our current zeny checks and zeny payment lines, into another if() statement that simply checks to see if we set a variable to anything other than 0. The variable we are going to use is our .heal_price and .buff_price
So let's make those changes:
if (.heal_price) {
    if (Zeny < .heal_price) {
        mes "I'm sorry, but you don't have enough zeny.";
        close;
    }
    Zeny -= .heal_price;
}
and
if (.buff_price) {
    if (Zeny < .buff_price) {
	mes "I'm sorry, but you don't have enough zeny.";
	close;
    }
    Zeny -= .buff_price;
}

That takes care of the first part. Now this is where we get a little technical. We are going to add another variable that gets set every time the server starts / reloads. We are going to call it .include_buffs. And let's just set it to 1 since it's going to be a simple toggle on/off setting.
Also, make sure to place it above the other variables we set beforehand:
.include_buffs = 1;

Now this may not seem obvious, but this setting is going to let us decide whether or not players receive buffs when they pay for heals (free of charge). Assuming we are all kind admins. So let's add a check in case 1:.
It's going to check if the variable is set to 0. And then simply wrap the existing break; command inside that check:
if (!.include_buffs) {
    break;
}

Doing this will let the script rn on through case 1: to case 2:. Next is a bit tricky, we are going to modify the way we set our .buff_price variable. To be more specific, we are going to use a (? :) check. For more information regarding (:?) look here: Conditional Operator.
Otherwise let's make the following changes:
.buff_price = ((.include_buffs)?0:5000);

Okay so this little bit of code is in short, just going to set the variable to 0 if we include buffs when they buy heals. Otherwise set the variable to 5000 which is what we said buffs cost normally.
Alright, so we only have 2 more changes to make, and that is simply 1 more check to determine whether or not we show them the buff price. Obviously, if buffs come with heals, we are going to just not show it so let's simply wrap the mes command dealing with showing buff pricing, into a check to see if .include_buffs is 0, additionally let's make that check also check to see if .buff_price is above 0.
if (!.include_buffs && .buff_price) {
    mes "^FF0000 *Note - AGI-UP + BLESSING Level 10 costs "+ .buff_price +" zeny.* ^000000";
}

And lastly, we are going to edit our menu. Again, this time we are going to use a (:?) check. We will be doing a little trick where we push the menu options down 1 slot. So let's edit our menu:
switch( select("Yes, heal me.", ( .include_buffs?"":"I want buffs" ), "No thank you") ) {

What this effectively allows us to do, is hide our option to choose "I want buffs" while still making sure the option "No thank you", which is now shown as option 2, doesn't get directed to case 2: since it is used for buffs only.
And that's it. Your script should look something like this:
prontera,150,180,4	script	Healer	4_F_ARUNA_POP,{
mes "[^0000FF Healer ^000000]";
mes "Would you like me to heal you?";
if (.heal_price) {
    mes "^FF0000 *Note - It costs "+ .heal_price +" zeny to get healed.* ^000000";
}
if (!.include_buffs && .buff_price){
    mes "^FF0000 *Note - AGI-UP + BLESSING Level 10 costs "+ .buff_price +" zeny.* ^000000";
}
switch( select("Yes, heal me.", ( .include_buffs?"":"I want buffs" ), "No thank you") ) {
	case 1:
		if (.heal_price) {
			if (Zeny < .heal_price) {
				mes "I'm sorry, but you don't have enough zeny.";
				close;
			}
			Zeny -= .heal_price;
		}
		percentheal 100,100;
		if (!.include_buffs) {
                    break;
                }
	
	case 2:
		if( .buff_price ){
			if( Zeny < .buff_price ) {
				mes "I'm sorry, but you don't have enough zeny.";
				close;
			}
			Zeny -= .buff_price;
		}
		sc_start SC_BLESSING,300000,10;
		sc_start SC_INC_AGI,300000,10;
		break;
}
close;

OnInit:
    .include_buffs = 1;
    .heal_price = 1000;
    .buff_price = ( (.include_buffs)?0:5000 );
    end;
}
So there we go, we now just made the Zeny Price for Heals & Buffs optional. As well as made it so buffs can be included with heals. Lastly, this will work for free should you choose to.

Part 2
Okay, here we're going to make it so, players in a guild receive additional buffs, at no extra cost.

So let's open up the script from before:
prontera,150,180,4	script	Healer	4_F_ARUNA_POP,{
mes "[^0000FF Healer ^000000]";
mes "Would you like me to heal you?";
if (.heal_price) {
    mes "^FF0000 *Note - It costs "+ .heal_price +" zeny to get healed.* ^000000";
}
if (!.include_buffs && .buff_price){
    mes "^FF0000 *Note - AGI-UP + BLESSING Level 10 costs "+ .buff_price +" zeny.* ^000000";
}
switch( select("Yes, heal me.", ( .include_buffs?"":"I want buffs" ), "No thank you") ) {
	case 1:
		if (.heal_price) {
			if (Zeny < .heal_price) {
				mes "I'm sorry, but you don't have enough zeny.";
				close;
			}
			Zeny -= .heal_price;
		}
		percentheal 100,100;
		if (!.include_buffs) {
                    break;
                }
	
	case 2:
		if( .buff_price ){
			if( Zeny < .buff_price ) {
				mes "I'm sorry, but you don't have enough zeny.";
				close;
			}
			Zeny -= .buff_price;
		}
		sc_start SC_BLESSING,300000,10;
		sc_start SC_INC_AGI,300000,10;
		break;
}
close;

OnInit:
    .include_buffs = 1;
    .heal_price = 1000;
    .buff_price = ( (.include_buffs)?0:5000 );
    end;
}

Alright, now let's add a mes command near the top that lets players know that they get more buffs if they are in a guild, also let's use ^0000FF as the color so it stands out:
mes "^0000FF *Note - Players in a guild receive additional buffs at no extra charge.* ^000000";

Next, beneath where we give them Increase AGI and Blessing, we are going to add a check to see if they are in a guild. Any guild doesn't matter so long as they are in one.
To do that we will need to use this command: getcharid(<type>{,"<character name>"})
if (getcharid(2)) {

Now we just need to give them more buffs. You can add as many as you like, but for this tutorial we're just going to give them Impositio Manus Level 5 and Assumptio Level 5:
    sc_start SC_IMPOSITIO,300000,5;
    sc_start SC_ASSUMPTIO,300000,5;
}

And that's it. We didn't do much here, but that's because the brunt of the work was done a long time ago. Now we are just expanding it with additional features. So your script should look something like this:
prontera,150,180,4	script	Healer	4_F_ARUNA_POP,{
mes "[^0000FF Healer ^000000]";
mes "Would you like me to heal you?";
if( .heal_price ){ mes "^FF0000 *Note - It costs "+ .heal_price +" zeny to get healed.* ^000000"; }
if( !.include_buffs && .buff_price ){ mes "^FF0000 *Note - AGI-UP + BLESSING Level 10 costs "+ .buff_price +" zeny.* ^000000"; }
mes "^0000FF *Note - Players in a guild receive additional buffs at no extra charge.* ^000000";
switch( select("Yes, heal me.", ( .include_buffs?"":"I want buffs" ), "No thank you") ) {
	case 1:
		if (.heal_price) {
			if (Zeny < .heal_price) {
				mes "I'm sorry, but you don't have enough zeny.";
				close;
			}
			Zeny -= .heal_price;
		}
		percentheal 100,100;
		if (!.include_buffs) {
                    break;
                }
	
	case 2:
		if (.buff_price) {
			if (Zeny < .buff_price) {
				mes "I'm sorry, but you don't have enough zeny.";
				close;
			}
			Zeny -= .buff_price;
		}
		sc_start SC_BLESSING,300000,10;
		sc_start SC_INC_AGI,300000,10;
		if (getcharid(2)) {
			sc_start SC_IMPOSITIO,300000,5;
			sc_start SC_ASSUMPTIO,300000,5;
		}
		break;
}
close;

OnInit:
    .include_buffs = 1;
    .heal_price = 0;
    .buff_price = ( (.include_buffs)?0:5000 );
end;
}
That's it for our healer, we probably won't need to come back to this ever again. But we will, I assure you.]]> Wed, 26 Nov 2014 01:01:00 +0000 http://herc.ws/board/blog/29/entry-97-intermediate-healer-buffer-script/ Basic Player vs Player Script http://herc.ws/board/blog/29/entry-96-basic-player-vs-player-script/ Basic Player vs Player Script ( 1 Part )
A Player vs Player script designed to introduce you to the basics needed to make them work.

Part 1
Okay this is going to be a short one. Despite what you may think, PvP scripts are actually very easy write and don't require much to get them to work.

Let's start off by making a floating NPC:
-    script    pvp_script    -1,{

So for this script, it is going to be a simple script that merely tells the player who it was that killed them. As well as giving he killer 1,000z. Simple right?
Let's start off by creating this label: OnPCKillEvent
OnPCKillEvent:

Now, this part is important. When a Player kills another player, 2 variables are set. killerrid (The Killer) and killedrid (The Dead one). Additionally, OnPCKillEvent automatically attaches the script to the killer.
So, before we decided to give them zeny, let's check to make sure they didn't commit suicide. Because that'd be cheating!
To do that we'll use the command: getcharid(<type>{,"<character name>"}) and check it against the id of the player killed. If they are the same, then the killer committed suicide, so we'll end the script early.
Let's add it in:
    if (getcharid(3) == killedrid) {
         end;
    }

Now that we've gotten that check out of the way, let's continue with the script and give the killer some zeny for doing a good job at slaying his opponent:
    Zeny += 1000;

Now we need to let the person who died know who killed him, so he can get revenge later. To do that we will use this command: attachrid(<account ID>).
Thankfully we already know what the dead person's account id is, because that is what killedrid is.
So let's add it in:
    attachrid(killedrid);

Now all that's left to do is let them know who killed them. We are going to use the command: dispbottom "<message>"; in combination with this command: rid2name(<rid>).
Now remember when I said there were 2 commands set, well we already used killedrid, so now we will be using killerrid to get the name of the killer.
Easy right? Let's add it in and end the script:
        dispbottom "You were killed by: "+ rid2name(killerrid) +"";
    end;
}

Once you've done that you are done. Your script should look something like this:
-	script	pvp_script	-1,{
OnPCKillEvent:
    if (getcharid(3) == killedrid) {
        end;
    }
    Zeny += 1000;
    attachrid( killedrid );
        dispbottom "You were killed by: "+ rid2name( killerrid ) +"";
    end;
}
I told you it was fast and simple.

Extra Information
There is just 1 more thing I want you to know about the label OnPCKillEvent and the variables killerrid and killedrid. If you read the link I gave you, it was very vague about what it does.
So let me explain in more detail:
1. When a player kills another player, the label OnPCKillEvent is triggered.
2. The script is automatically attached to the killer.
3. (Important) The variable ' killedrid ' holds the dead person's account_id number. BUT, only the killer has this variable.
4. (Important) The variable ' killerrid ' holds the killing person's account_id number. BUT, only the dead person has this variable.
So that's it, just remember that when writing your own scripts.]]> Tue, 25 Nov 2014 23:52:00 +0000 http://herc.ws/board/blog/29/entry-96-basic-player-vs-player-script/ Basic Floating Rates Script http://herc.ws/board/blog/29/entry-95-basic-floating-rates-script/ Basic Floating Rates Script ( 2 Parts )
Here we will create an npc that will adjust the base & job experience rates.

Part 1
Alright, so we're going to start off by making a floating npc header. It's similar to a normal npc header with the exception of replacing the <map_name>,<x>,<y>,<facing> with a simply hyphen ( - ), and the <sprite_id> with -1.

So let's make our floating npc header and call our npc floating_rates:
-    script    floating_rates    -1,{

Alright, since this is our third script in the beginner's series, we're going to speed things up a bit by not taking so much time to explain things ( this sentence & mandatory explanations being the exception ).
Now, since we want our script to activate everyday of the week, and change daily, we are going to use a label called: OnClock<hour><minute>: The time we are going to use is 0000:
OnClock0000:

Okay, now it's time to start adding in where we change the experience rates, but first we need to set 2 variables to a random value between 150 & 200.
To do so we use this command: rand(<number>{,<number>}); We're going to use scope variables, and we're going to call them base_exp & job_exp.
So go ahead and add that beneath our OnClock label:
    .@base_exp = rand(150,200);
    .@job_exp = rand(150,200);

We got that taken care of. Now we are going to actually change the base & job experience rates. To do that we need to use this command: setbattleflag "<battle flag>",<value>;
A list of battle flags can be found in the files listed here: Battle Flags. But we are only going to be using the following flags: base_exp_rate & job_exp_rate
    setbattleflag "base_exp_rate", .@base_exp;
    setbattleflag "job_exp_rate", .@job_exp;

Alright, that's everything we need to do. So let's end the script and close it up:
    end;
}

When you're done, your script should look something like this:
-	script	floating_rates	-1,{
OnClock0000:
    .@base_exp = rand(150,200);
    .@job_exp = rand(150,200);
    setbattleflag "base_exp_rate", .@base_exp;
    setbattleflag "job_exp_rate", .@job_exp;
    end;
}
And, now whenever your players kill a monster they will get that modified experience rate, that changes everyday at midnight.

Part 2
Okay, so last lesson we made a very basic floating rates npc that changes the rates everyday. However, now we are going to change that npc to only change rates during weekends.

Let's start by opening up our script:
-	script	floating_rates	-1,{
OnClock0000:
    .@base_exp = rand(150,200);
    .@job_exp = rand(150,200);
    setbattleflag "base_exp_rate", .@base_exp;
    setbattleflag "job_exp_rate", .@job_exp;
    end;
}

So, to make it only work for Friday, Saturday and Sunday, we are going to change our label OnClock0000: to this label: On<weekday><hour><minute>:.
So let's change it for Firday same time:
OnFri0000:

Okay now that we got that taken care of, rates will change to a new random amount every Friday. However we want this to only last for the weekend, so we need to change them back starting Monday. That's right you guessed it, very similar setup but this time we'll be setting the rates back to normal so let's do it:
OnMon0000:
    setbattleflag "base_exp_rate", 100;
    setbattleflag "job_exp_rate", 100;
    end;

Right now your script should look something like this:
-	script	floating_rates	-1,{
OnFri0000:
    .@base_exp = rand(150,200);
    .@job_exp = rand(150,200);
    setbattleflag "base_exp_rate", .@base_exp;
    setbattleflag "job_exp_rate", .@job_exp;
    end;
OnMon0000:
    setbattleflag "base_exp_rate", 100;
    setbattleflag "job_exp_rate", 100;
    end;
}

As of right now it's almost done. Let's just edit it a bit, so that we let player's know when the experience rates change and what they changed to.
To do that we are going to use this command: announce "<text>",<flag>{,<fontColor>{,<fontType>{,<fontSize>{,<fontAlign>{,<fontY>}}}}}; in combination with this command: getbattleflag("<battle flag>")
The announcement_flag we'll be using is bc_all with 0x00FFFF as the color. For other flags look here: Broadcast Flags. Additionally, you can use other hex color codes for the broadcast color in this format: 0xRRGGBB
Now then let's add 1 announcement when we increase the rates:
announce "Bonus Experience Weekend has just started! Base Exp: +"+ (getbattleflag("base_exp_rate") - 100) +"% | Job Exp: +"+ (getbattleflag("job_exp_rate") - 100) +"% !!",bc_all,0x00FFFF;

And 1 announcement when we set the rates back:
announce "Bonus Experience Weekend has ended.",bc_all,0x00FFFF;

Make sure you added those announcements under the correct label, if you got them backwards you'll be confusing your players. Although, we are almost done so let's finish this.
The last thing we're going to do is add 1 more announcement that occurs every hour, to let player's know it is bonus exp weeked.
To do that we're going to use the label: OnMinute<minute>: and we are going to use 00 as the minute, additionally we need to use this command: gettime(<type>) so we can find out the day.
Mainly we need to check if it's Friday, Saturday or Sunday. So let's add it in:
OnMinute00:
    if (!gettime(4) || gettime(4) >= 5){
	announce "Bonus Experience Weekend in progress! Base Exp: +"+ (getbattleflag("base_exp_rate") - 100) +"% | Job Exp: +"+ (getbattleflag("job_exp_rate") - 100) +"% !!",bc_all,0x00FFFF;
    }
    end;

When you're all done your script should look like this:
-	script	floating_rates	-1,{
OnFri0000:
    .@base_exp = rand(150,200);
    .@job_exp = rand(150,200);
    setbattleflag "base_exp_rate", .@base_exp;
    setbattleflag "job_exp_rate", .@job_exp;
    announce "Bonus Experience Weekend has just started! Base Exp: +"+ (getbattleflag("base_exp_rate") - 100) +"% | Job Exp: +"+ (getbattleflag("job_exp_rate") - 100) +"% !!",bc_all,0x00FFFF;
    end;
OnMon0000:
    setbattleflag "base_exp_rate", 100;
    setbattleflag "job_exp_rate", 100;
    announce "Bonus Experience Weekend has ended.",bc_all,0x00FFFF;
    end;
	
OnMinute00:
    if (!gettime(4) || gettime(4) >= 5){
        announce "Bonus Experience Weekend in progress! Base Exp: +"+ (getbattleflag("base_exp_rate") - 100) +"% | Job Exp: +"+ (getbattleflag("job_exp_rate") - 100) +"% !!",bc_all,0x00FFFF;
	}
    end;
}
Save it and we are done. You just finished creating a Floating Rates NPC.]]> Tue, 25 Nov 2014 21:22:00 +0000 http://herc.ws/board/blog/29/entry-95-basic-floating-rates-script/ Basic Item Trader Script http://herc.ws/board/blog/29/entry-94-basic-item-trader-script/ Basic Item Trader Script ( 2 Parts )
A basic item trader script. Here we will learn how to give players an item in exchange for other items.

Part 1
Alright, since you're here, I'm goign to assume you completed the previous guide and created a working Healer & Buffer script with a zeny cost. Or, you already know all that.
So let's start off by making our npc header. Don't forget to use those constants for sprite_id. For a list of sprite IDs and their constants check here: Sprite_IDs Credits: Ai4rei. Additonally, the constants for those NPCs are also located in const.txt.

For this npc, I'm going to be using the vending machine sprite and I'm going to name my npc Vending machine. You're free to choose your own sprite and name.
prontera,152,180,4    script    Vending Machine    2_VENDING_MACHINE1,{

So let's start off by making the variables we'll be using for this script. And we're going to place those under the label: OnInit: again. We are also going to be using npc_variables as well. The only difference is that this we're going to be using arrays via the command: setarray <array name>[<first value>],<value>{,<value>...<value>}; and don't forget to end it all with the end; command.
Now, our script is going to give a Player, 1 Valkyrie_Helm for 5 different items. So let's add it in:
OnInit:
    .reward_item = Valkyrie_Helm;
    .reward_amount = 1;
    setarray .request_items[0], Red_Potion, White_Potion, Blue_Potion, Jellopy, Poring_Card;
    setarray .required_amount[0], 10, 5, 1, 1000, 1;
    end;

This tells us, that we're going to be giving a player, 1 Valkyrie helm for 10 Red Potions, 5 White Potions, 1 Blue Potion, 1000 Jellopy and 1 Poring card. Now that's easy!
Now we need to add in all of our mes commands to give our npc some dialogue. But, since this npc is gonna do a bit of talking let's save it's name in a temporary scope_variable:
.@npc_name$ = "[^FF0000 Vending Machine ^000000]";

Now the variable .@npc_name$ holds all that information inside of it. And it's definitely a lot easier to type. So let's add the mes command beneath that with our variable:
mes .@npc_name$;

You'll notice I didn't use any quotation marks for that. This is because we used a string variable. And our string variable already has those quotation marks saved inside of it. Now then, let's add in the rest of the mes commands to let player's know how much 1 valkyrie helm costs. To do that were going to be utilizing the command: getitemname(<item id>) and where it asks for <item_id> we're going to be using our variables. So let's add the following lines in:
mes "I will give you "+ .reward_amount +" "+ getitemname(.reward_item) +",";
mes "for the following items:";
mes ""+ getitemname(.required_items[0]) +" x"+ .required_amount[0] +"";
mes ""+ getitemname(.required_items[1]) +" x"+ .required_amount[1] +"":
mes ""+ getitemname(.required_items[2]) +" x"+ .required_amount[2] +"":
mes ""+ getitemname(.required_items[3]) +" x"+ .required_amount[3] +"":
mes ""+ getitemname(.required_items[4]) +" x"+ .required_amount[4] +"":

See, that wasn't too hard. It's practically the same thing as the reward variables, just with the extra [#] added. Okay, next let's add in our menu. This time we're going to keep it to 2 options, so we're going to make it that if they choose option 2, end the script with close; since we used mes earlier.
if (select("Trade in items", "That's a rip off!") == 2) {
    close;
}

Okay, now that we got that taken care of. We need to add a few checks. The first check being whether or not they have those items. To do that we're going to use the command: countitem(<item id>).
Keep in mind that since we have 5 items to check for, we're going to be utilizing the | | operator. Now this is where things get a little technical, after each | | we're going to add the next check on the line beneath.
We're doing this to keep the script nice and neat. Would you rather look at 5 short lines, or 1 really long line that makes your head turn? So let's stick to 5 short lines.
Let's add our check below the if() statement we did above. It should look something like this:
if ((countitem(.required_items[0]) < .required_amount[0]) ||
    (countitem(.required_items[1]) < .required_amount[1]) ||
    (countitem(.required_items[2]) < .required_amount[2]) ||
    (countitem(.required_items[3]) < .required_amount[3]) ||
    (countitem(.required_items[4]) < .required_amount[4])) {
        mes "You don't have all the required items.";
        close;
}

Now that we added the check to see if they have all the items, it's time to delete those items, and give them the reward! The commands that let us do that are the following respectively: delitem <item id>,<amount>{,<account ID>}; and getitem <item id>,<amount>{,<account ID>};
So let's add that in below our check, and remember to use those variables:
delitem .required_items[0], .required_amount[0];
delitem .required_items[1], .required_amount[1];
delitem .required_items[2], .required_amount[2];
delitem .required_items[3], .required_amount[3];
delitem .required_items[4], .required_amount[4];
getitem .reward_item, .reward_amount;

Okay, now there's only 1 more thing to do, and that's add the last } to the very bottom of our script. After you add that you're done. You now have a working item trader script. It should look something like this:
prontera,154,180,4	script	Vending Machine	2_VENDING_MACHINE1,{
.@npc_name$ = "[^FF0000 Vending Machine ^000000]";
mes .@npc_name$;
mes "I will give you "+ .reward_amount +" "+ getitemname(.reward_item) +",";
mes "for the following items:";
mes ""+ getitemname(.required_items[0]) +" x"+ .required_amount[0] +"";
mes ""+ getitemname(.required_items[1]) +" x"+ .required_amount[1] +"";
mes ""+ getitemname(.required_items[2]) +" x"+ .required_amount[2] +"";
mes ""+ getitemname(.required_items[3]) +" x"+ .required_amount[3] +"";
mes ""+ getitemname(.required_items[4]) +" x"+ .required_amount[4] +"";
if (select("Trade in items", "That's a rip off!") == 2) {
	close;
}
if ((countitem(.required_items[0]) < .required_amount[0]) ||
    (countitem(.required_items[1]) < .required_amount[1]) ||
    (countitem(.required_items[2]) < .required_amount[2]) ||
    (countitem(.required_items[3]) < .required_amount[3]) ||
    (countitem(.required_items[4]) < .required_amount[4])){
        mes "You don't have all the required items.";
	close;
}
delitem .required_items[0], .required_amount[0];
delitem .required_items[1], .required_amount[1];
delitem .required_items[2], .required_amount[2];
delitem .required_items[3], .required_amount[3];
delitem .required_items[4], .required_amount[4];
getitem .reward_item, .reward_amount;
close;

OnInit:
    .reward_item = Valkyrie_Helm;
    .reward_amount = 1;
    setarray .required_items[0], Red_Potion, White_Potion, Blue_Potion, Jellopy, Poring_Card;
    setarray .required_amount[0], 10, 5, 1, 1000, 1;
    end;
}
You just finished making a working item trader npc. But it's not 100% done yet. We need to do a few more things. We'll deal with those in the next lesson. For now look at it, and be proud.

Part 2
Okay, last lesson I mentioned how the script wasn't 100% done yet, because there were a few things we needed to take care of. So let's knock those out.

Firstly, let's start by opening the script from last time:
prontera,154,180,4	script	Vending Machine	2_VENDING_MACHINE1,{
.@npc_name$ = "[^FF0000 Vending Machine ^000000]";
mes .@npc_name$;
mes "I will give you "+ .reward_amount +" "+ getitemname(.reward_item) +",";
mes "for the following items:";
mes ""+ getitemname(.required_items[0]) +" x"+ .required_amount[0] +"";
mes ""+ getitemname(.required_items[1]) +" x"+ .required_amount[1] +"";
mes ""+ getitemname(.required_items[2]) +" x"+ .required_amount[2] +"";
mes ""+ getitemname(.required_items[3]) +" x"+ .required_amount[3] +"";
mes ""+ getitemname(.required_items[4]) +" x"+ .required_amount[4] +"";
if (select("Trade in items", "That's a rip off!") == 2) {
	close;
}
if ((countitem(.required_items[0]) < .required_amount[0]) ||
    (countitem(.required_items[1]) < .required_amount[1]) ||
    (countitem(.required_items[2]) < .required_amount[2]) ||
    (countitem(.required_items[3]) < .required_amount[3]) ||
    (countitem(.required_items[4]) < .required_amount[4])){
        mes "You don't have all the required items.";
	close;
}
delitem .required_items[0], .required_amount[0];
delitem .required_items[1], .required_amount[1];
delitem .required_items[2], .required_amount[2];
delitem .required_items[3], .required_amount[3];
delitem .required_items[4], .required_amount[4];
getitem .reward_item, .reward_amount;
close;

OnInit:
    .reward_item = Valkyrie_Helm;
    .reward_amount = 1;
    setarray .required_items[0], Red_Potion, White_Potion, Blue_Potion, Jellopy, Poring_Card;
    setarray .required_amount[0], 10, 5, 1, 1000, 1;
    end;
}

Alright, now that we opened this up, we need to add a check to make sure the player has enough inventory space, and free-weight to carry the reward.
To do so we need to use the command: checkweight(<item id>,<amount>{,<item id>,<amount>,<item id>,<amount>,...}); Only thin is, we're going to check to see if the command fails using this operator: !
So let's go ahead and add that above the first delitem command:
if (!checkweight(.reward_item, .reward_amount)) {

This tells us that, if true ( if the command fails ) to do something. In our case, we want to just tell the player they don't have enough free-space/weight to receive the item. Then we're going to add a close; command to end the script early. And lastly close the check with }.
So let's go ahead and do that, it should look like this when it's done:
    mes "You don't have enough free inventory space or weight to receive this item.";
    close;
}

Okay, now the script is finished, and you technically don't need to do anything else to it. But, we're here to learn! So we're going to clean up the script a bit using a loop.
The loop we will be using is called: while (<condition>) <statement>; There are other loops that can get the job done, but I feel like this one is best suited since it's simple.
Alright, so go ahead and delete the following from your script:
mes ""+ getitemname(.required_items[0]) +" x"+ .required_amount[0] +"";
mes ""+ getitemname(.required_items[1]) +" x"+ .required_amount[1] +"";
mes ""+ getitemname(.required_items[2]) +" x"+ .required_amount[2] +"";
mes ""+ getitemname(.required_items[3]) +" x"+ .required_amount[3] +"";
mes ""+ getitemname(.required_items[4]) +" x"+ .required_amount[4] +"";

Okay now where those mes commands used to be, we're going to add our loop. We're goign to be using a scope_variable .@ and we're going to compare it to a value we obtain with this command: getarraysize(<array name>).
So go ahead and add the following:
while (.@i < getarraysize(.required_items)) {

Just a note, .@i can be any variable name. It doesn't even need to be a scope_variable. But since we only need the variable for this 1 loop, we use a scope_variable, so it's memory isn't saved once the script ends. However, .@i is most commonly used in cases like these. Now then let's continue.
Beneath that we're going to be adding 1 mes command followed by setting the variable .@i + 1.
On the line after that we're going to close the loop with }. I'm sure you've noticed I keep telling you to close either a script, if() statement, loop and the like with }. This is because we always need to make sure to close a command with a right-curly bracket } whenever a left-curly bracket { is used.

Now, the mes command we're going to use is very similar to the ones we deleted. The only difference is, instead of using [0] or or [2], we'll be replacing that with [.@i] as such:
    mes ""+ getitemname(.required_items[.@i]) +" x"+ .required_amount[.@i] +"";
    ++.@i;
}

Okay since that's done we're about 80% done making this script nice and clean. There is only 1 more thing to do, and that's add 1 more while() loop. But this time, we're going to be replacing those delitem() commands with the loop. The difference is, instead of using .@i we're going to switch it to .@j it is a lower-case J. If you're having a hard time reading that. So taking a look at our previous loop as an example, let's replace those delitem() commands with a loop:
while (.@j < getarraysize(.required_items)) {
    delitem .required_items[.@j], .required_amount[.@j];
    ++.@j;
}

Alright, now your script should look something like this:
prontera,154,180,4	script	Vending Machine	2_VENDING_MACHINE1,{
.@npc_name$ = "[^FF0000 Vending Machine ^000000]";
mes .@npc_name$;
mes "I will give you "+ .reward_amount +" "+ getitemname(.reward_item) +",";
mes "for the following items:";
while (.@i < getarraysize(.required_items)){
    mes ""+ getitemname(.required_items[.@i]) +" x"+ .required_amount[.@i] +"";
    ++.@i;
}
if (select("Trade in items", "That's a rip off!") == 2) {
    close;
}
if ((countitem(.required_items[0]) < .required_amount[0]) ||
    (countitem(.required_items[1]) < .required_amount[1]) ||
    (countitem(.required_items[2]) < .required_amount[2]) ||
    (countitem(.required_items[3]) < .required_amount[3]) ||
    (countitem(.required_items[4]) < .required_amount[4])){
	mes "You don't have all the required items.";
	close;
}
if (!checkweight(.reward_item, .reward_amount)){
    mes "You don't have enough free inventory space or weight to receive this item.";
    close;
}
while (.@j < getarraysize(.required_items)){
    delitem .required_items[.@j], .required_amount[.@j];
    ++.@j;
}
getitem .reward_item, .reward_amount;
close;

OnInit:
    .reward_item = Valkyrie_Helm;
    .reward_amount = 1;
    setarray .required_items[0], Red_Potion, White_Potion, Blue_Potion, Jellopy, Poring_Card;
    setarray .required_amount[0], 10, 5, 1, 1000, 1;
    end;
}
Go ahead and save that, because we are done.]]> Tue, 25 Nov 2014 18:30:00 +0000 http://herc.ws/board/blog/29/entry-94-basic-item-trader-script/ <![CDATA[Basic Healer & Buffer Script]]> http://herc.ws/board/blog/29/entry-93-basic-healer-buffer-script/ Basic Healer & Buffer Script (5 Parts)
A Basic Healer Script. Here we will cover most, if not all of the basics of scripting.

Part 1
Okay, for this healer were going to create one that heals you 100% HP&SP when you click on it and choose heal me.
So let's start off by wring the NPC header.
<map name>,<x>,<y>,<facing>%TAB%script%TAB%<NPC Name>%TAB%<sprite id>,{<code>}
 // Facing Directions, each number is the equivalent to a point on a compass.
 [1][0][7]
 [2]   [6]
 [3][4][5]

Alright time to begin, starting with the NPC header:
prontera,150,180,4    script    Healer    4_F_ARUNA_POP,{

Now that we have the header out of the way it's time to write a little bit of dialogue.
To do that, we're going to use the command: mes "<text>"; Additionally, we are going to be using the color codes, to make the name of the healer appear blue within the text box.
mes "[^0000FF Healer ^000000]";
mes "Would you like me to heal you?";

Okay, we got the little bit of dialogue out of the way. Now let's give them the choice of whether or not they want to be healed.
To do so, we're going to be using a combination of 2 commands. The first being: if( <condition> ) { <statement> }; and Second: select("<option>"{,"<option>",...})
But we are also going to end the script early, if they decided to choose: ' No thank you. ' by using the command: close;
The reason we are using the close command, is because when we used mes, it caused a text window to open up. And we need to close that window. Simple right?
*Note - Options can be grouped together, separated by the character ' : '.*
If you are unsure what I mean by " condition " take a look at this: Operators
if (select("Yes, heal me.", "No thank you.") == 2) {
    close;
}

Now that we have that finished, it is time to heal them for 100% HP&SP using the command: percentheal <hp>,<sp>;
And also end the script. Again, using the close command.
percentheal 100,100;
close;

Now all we need to do is add the last } to the end of our script, so that it knows there is nothing more to add.
Once you're done, your script should look something like this:
prontera,150,180,4    script    Healer    4_F_ARUNA_POP,{
mes "[^0000FF Healer ^000000]";
mes "Would you like me to heal you?";
if (select("Yes, heal me.", "No thank you.") == 2) {
    close;
}
percentheal 100,100;
close;
}
And that's it for your first script. You just created a healer npc.

Part 2
Okay, firstly you should have already completed Part 1 of this tutorial. If not you need to do so to follow along.

In part 2, we are going to be making a small edit to our script to let player's know it cost zeny to use the healer. Then we are going to check if they have enough zeny. If they do, we'll take some away and heal them.
Let's start by opening up the script we made in Part 1.
prontera,150,180,4    script    Healer    4_F_ARUNA_POP,{
mes "[^0000FF Healer ^000000]";
mes "Would you like me to heal you?";
if (select("Yes, heal me.", "No thank you.") == 2) {
    close;
}
percentheal 100,100;
close;
}

Okay, let's add the following line above the menu options:
mes "^FF0000 *Note - It costs 1,000 zeny to get healed.* ^000000";

Next, directly above percentheal 100,100; we're going to be adding our check to see if they have enough zeny. If they do not, we'll be telling them that they don't have enough zeny. Then we'll end the script.
To do so, we're going to be using the command: if( <condition> ) { <statement> };
If you are unsure what I mean by " condition " take a look at this: Operators
if (Zeny < 1000) {
    mes "I'm sorry, but you don't have enough zeny.";
    close;
}

Okay we got the check out of the way. Now we just need to take the zeny away from them if they do have enough zeny.
To do that we'll be setting the Constant Variable Zeny to a value of Zeny - 1000. To see how this is done look here: Assigning variables
Now then, lets add it in:
Zeny -= 1000;

And that's all there is to edit. When you're done it should look something like this:
prontera,150,180,4	script	Healer	4_F_ARUNA_POP,{
mes "[^0000FF Healer ^000000]";
mes "Would you like me to heal you?";
mes "^FF0000 *Note - It costs 1,000 zeny to get healed.* ^000000";
if (select("Yes, heal me.", "No thank you.") == 2) {
    close;
}
if (Zeny < 1000) {
    mes "I'm sorry, but you don't have enough zeny.";
    close;
}
Zeny -= 1000;
percentheal 100,100;
close;
}
And that's it, you just finished editing your script, and now it costs players 1,000 zeny to get healed.

Part 3
Alright, to start this off. I'm assuming you already finished Part 1 & 2. If not, I recommend you do so,
since we will be using those scripts to make this one. I will attempt to continue this pattern until we deviate away from the healer and move on to a different type of script.

So first, let's open up the script we made in Part 2.
prontera,150,180,4	script	Healer	4_F_ARUNA_POP,{
mes "[^0000FF Healer ^000000]";
mes "Would you like me to heal you?";
mes "^FF0000 *Note - It costs 1,000 zeny to get healed.* ^000000";
if (select("Yes, heal me.", "No thank you.") == 2) {
    close;
}
if (Zeny < 1000) {
    mes "I'm sorry, but you don't have enough zeny.";
    close;
}
Zeny -= 1000;
percentheal 100,100;
close;
}

Let's start by adding a MES to show how much they cost. For this script were going to make it nice and cheap. 5,000z to get both INCREASED AGI & BLESSING Lvl 10.
And were going to add this right above our menu options.
mes "^FF0000 *Note - INCREASED AGI + BLESSING Level 10 costs 5,000 zeny.* ^000000";

Now that people know we offer buffs, we need to give them the option to choose to get buffed.
So lets modify our menu to have a 3rd option.
if (select("Yes, heal me.", "I want buffs", "No thank you.") == 3) {
    close;
}

Now that we got that out of the way. It's time to modify our zeny check. It's going to be customized a little bit.
Were now going to use | | and && operators in our checks.
So go ahead and find our zeny check and change it to the below:
if ((Zeny < 1000 && @menu == 1) || (Zeny < 5000 && @menu == 2)) {
    mes "I'm sorry, but you don't have enough zeny.";
    close;
}

Your probably wondering why were using @menu == 1 or @menu == 2. This is because when ever a menu option is selected, the variable @menu is set to that option. So, the first option is equal to 1, and the second is equal to 2, so on and so forth.

At anyrate, since we are still in the beginner section of scripting, were going to be adding 1 more check to our script.
So go ahead and add the following to your script beneath the checks we did above:
if (@menu == 1) {
    Zeny -= 1000;
    percentheal 100,100;
}

However, this isn't complete. We still need to add the last part, which deals with our buffs.
To do that we're going to be using the command: sc_start <effect type>,<ticks>,<value 1>{,<rate>,<flag>{,<GID>}};
Where, effect type is the buff we want to give them, ticks is how long it will last in 1/1000ths of a second, and value is the level of the buff.

In our case, we are using Blessing Level 10 and AGI-UP Level 10. And to keep things simple, we're going to make it last for 5mins each.
If you wish to add other status-effects then look in this file: const.txt. It will be the things starting with: SC_ .
So, let's start by finding our previous check and find: } . And add the following next to it:
else {
    Zeny -= 5000;
    sc_start SC_BLESSING,300000,10;
    sc_start SC_INC_AGI,300000,10;
}

So your probably looking at the 300000 and wondering why it's like that. Well the answer is simple.
Ticks are 1/1,000ths of a second. So to find 5 minutes we do the following math.
1 * 1,000 = 1 second * 60 = 60,000 OR 1 Minute * 5 = 300,000 OR 5 Minutes. So now that we have our number we just put it in.
Okay, now that it's done. Your script should look like the following:
prontera,150,180,4	script	Healer	4_F_ARUNA_POP,{
mes "[^0000FF Healer ^000000]";
mes "Would you like me to heal you?";
mes "^FF0000 *Note - It costs 1,000 zeny to get healed.* ^000000";
mes "^FF0000 *Note - INCREASED AGI + BLESSING Level 10 costs 5,000 zeny.* ^000000";
if (select("Yes, heal me.", "I want buffs", "No thank you.") == 3) {
	close;
}
if ((Zeny < 1000 && @menu == 1) || (Zeny < 5000 && @menu == 2)) {
	mes "I'm sorry, but you don't have enough zeny.";
	close;
}
if (@menu == 1) {
	Zeny -= 1000;
	percentheal 100,100;
} else {
	Zeny -= 5000;
	sc_start SC_BLESSING,300000,10;
	sc_start SC_INC_AGI,300000,10;
}
Zeny -= 1000;
percentheal 100,100;
close;
}

Now we're just going to delete those last 2 lines above close;
When you're finished deleting them, your script will be done. And it should look something like this:
prontera,150,180,4	script	Healer	4_F_ARUNA_POP,{
mes "[^0000FF Healer ^000000]";
mes "Would you like me to heal you?";
mes "^FF0000 *Note - It costs 1,000 zeny to get healed.* ^000000";
mes "^FF0000 *Note - INCREASED AGI + BLESSING Level 10 costs 5,000 zeny.* ^000000";
if (select("Yes, heal me.", "I want buffs", "No thank you.") == 3) {
	close;
}
if ((Zeny < 1000 && @menu == 1) || (Zeny < 5000 && @menu == 2)) {
	mes "I'm sorry, but you don't have enough zeny.";
	close;
}
if (@menu == 1) {
	Zeny -= 1000;
	percentheal 100,100;
} else {
	Zeny -= 5000;
	sc_start SC_BLESSING,300000,10;
	sc_start SC_INC_AGI,300000,10;
}
close;
}
And that's it. You just finished editing your script and now players have the option to receive Increased AGI and Blessing Level 10 at the cost of 5,000 zeny.

Part 4
Okay, so by now, you've learned how to make a pretty standard healing npc. But, it looks kind of messy. So in this lesson, we're going to clean it up, by getting rid of some of those if( stantements ).

So as always, let's start by opening up the previous script:
prontera,150,180,4	script	Healer	4_F_ARUNA_POP,{
mes "[^0000FF Healer ^000000]";
mes "Would you like me to heal you?";
mes "^FF0000 *Note - It costs 1,000 zeny to get healed.* ^000000";
mes "^FF0000 *Note - INCREASED AGI + BLESSING Level 10 costs 5,000 zeny.* ^000000";
if (select("Yes, heal me.", "I want buffs", "No thank you.") == 3) {
	close;
}
if ((Zeny < 1000 && @menu == 1) || (Zeny < 5000 && @menu == 2)) {
	mes "I'm sorry, but you don't have enough zeny.";
	close;
}
if (@menu == 1) {
	Zeny -= 1000;
	percentheal 100,100;
} else {
	Zeny -= 5000;
	sc_start SC_BLESSING,300000,10;
	sc_start SC_INC_AGI,300000,10;
}
close;
}

What were going to do here is just delete everything after the last mes command. So highlight everything beneath that and just press DELETE or BACKSPACE ( your choice =P ).

When your done your script should look like this:
prontera,150,180,4	script	Healer	4_F_ARUNA_POP,{
mes "[^0000FF Healer ^000000]";
mes "Would you like me to heal you?";
mes "^FF0000 *Note - It costs 1,000 zeny to get healed.* ^000000";
mes "^FF0000 *Note - INCREASED AGI + BLESSING Level 10 costs 5,000 zeny.* ^000000";

Looks like we went back to the drawing board. But don't worry, you'll be doing this a lot down the line when writing your own scripts. Finding better ways to write it and such. So, let's start by adding the following line beneath it.

This will serve as our new menu:
switch(select("Yes, heal me.", "I want buffs", "No thank you")) {
I'm sure you've noticed the ' switch ' which took the place of ' if '. We also got rid of the ' == 3 ' part. This is because switch is much cleaner and easier to read. But, first let's explain what it does. Simply, all it does is cycle through labels called: case 1: case 2: etc... depending on the value of a variable or number. In our case, it's the variable @menu which will have either a value of 1, 2 or 3 because of our menu.

If you want a further explanation, you can click the spoiler below for a bit more detail. Otherwise, let's continue to the next step.
Spoiler
Okay, let's add the sub-label: case 1: to our script. This will deal with players click on " Yes, heal me. ". Let's also add the zeny check & percentheal in there as well.

So add the following:
case 1:
	if (Zeny < 1000) {
		mes "I'm sorry, you don't have enough zeny.";
		close;
	}
	Zeny -= 1000;
	percentheal 100,100;
	break;

That's done. I'm sure you see the command: break; there. What this does is allow us to ' exit ', a pair of { }. Doing so, will allow us to continue on with the script if there is some other things to do. You can take a look at the spoiler above to see how we utilize this. Other wise, let's go a head and make the second label: case 2: beneath all of that.

This one will deal with when they click on " I want buffs. ", so we are going to be adding the zeny check for that, along with the buffs:
case 2:
	if (Zeny < 5000) {
		mes "I'm sorry, but you don't have enough zeny.";
		close;
	}
	Zeny -= 5000;
	sc_start SC_BLESSING,300000,10;
	sc_start SC_INC_AGI,300000,10;
	break;

Now that we got that out of the way. Let's add } to the end of that, to let the script know were done with the: switch() command. Then directly beneath that, were going to add: close; To let the script knows that were ending it. Followed by the final } so that the script knows that there is nothing more to do.
}
close;
}

Once your done with that, your script should look something like the below:
prontera,150,180,4	script	Healer	4_F_ARUNA_POP,{
mes "[^0000FF Healer ^000000]";
mes "Would you like me to heal you?";
mes "^FF0000 *Note - It costs 1,000 zeny to get healed.* ^000000";
mes "^FF0000 *Note - INCREASED AGI + BLESSING Level 10 costs 5,000 zeny.* ^000000";
switch( select("Yes, heal me.", "I want buffs", "No thank you") ) {
	case 1:
		if (Zeny < 1000) {
			mes "I'm sorry, but you don't have enough zeny.";
			close;
		}
		Zeny -= 1000;
		percentheal 100,100;
		break;
	
	case 2:
		if (Zeny < 5000) {
			mes "I'm sorry, but you don't have enough zeny.";
			close;
		}
		Zeny -= 5000;
		sc_start SC_BLESSING,300000,10;
		sc_start SC_INC_AGI,300000,10;
		break;
}
close;
}
And there you go, you just finished cleaning up your script. It looks much better, and it still does the exact same thing! Who would of thought.

Part 5
Alright, so far we've completed Parts 1 -> 4. And we have a working script because of it. Now, what we need to do is, make it easily configurable. Sure, we could scroll through the script, and change the zeny prices. But if we do that, we might make a mistake. So what were going to do is, add a label called: OnInit: in our script. This label will active each and every time the server starts up, or scripts are reloaded.
And under this label we'll be adding our variables, which will be our focus for when we want to configure things in our script.

For a list of all variable types look here: Variables
So go ahead and open up the script from the last lesson:
prontera,150,180,4	script	Healer	4_F_ARUNA_POP,{
mes "[^0000FF Healer ^000000]";
mes "Would you like me to heal you?";
mes "^FF0000 *Note - It costs 1,000 zeny to get healed.* ^000000";
mes "^FF0000 *Note - INCREASED AGI + BLESSING Level 10 costs 5,000 zeny.* ^000000";
switch( select("Yes, heal me.", "I want buffs", "No thank you") ) {
	case 1:
		if (Zeny < 1000) {
			mes "I'm sorry, but you don't have enough zeny.";
			close;
		}
		Zeny -= 1000;
		percentheal 100,100;
		break;
	
	case 2:
		if (Zeny < 5000) {
			mes "I'm sorry, but you don't have enough zeny.";
			close;
		}
		Zeny -= 5000;
		sc_start SC_BLESSING,300000,10;
		sc_start SC_INC_AGI,300000,10;
		break;
}
close;
}

We are going to add the: OnInit: label beneath the final: close; command. But let's also add a couple of npc_variables there as well. And let's name those variables: heal_price and buff_price .

Remeber, those are NPC variables. So let's go ahead and add the following:
OnInit:
.heal_price = 1000;
.buff_price = 5000;

Here you can see we used the set command. This is because we are telling the script to set those variables, to those values. In this case, .heal_price to 1,000 and .buff_price to 5,000 since that is what our script uses as prices for healing and buffing. Now, we really should add this command beneath that: end; .
Go ahead and click that link to find out why we need to add it.
end;

Alright, we have officially created variables. However as they are now, they aren't doing anything and just taking up space. So now were going to put them to use. Let's comb through our script and find all of our zeny checks. Let's replace all those: 1000 and 5000 with the corresponding variables.
When your done, your script should look like this so far:
prontera,150,180,4	script	Healer	4_F_ARUNA_POP,{
mes "[^0000FF Healer ^000000]";
mes "Would you like me to heal you?";
mes "^FF0000 *Note - It costs 1,000 zeny to get healed.* ^000000";
mes "^FF0000 *Note - INCREASED AGI + BLESSING Level 10 costs 5,000 zeny.* ^000000";
switch( select("Yes, heal me.", "I want buffs", "No thank you") ) {
	case 1:
		if (Zeny < .heal_price) {
			mes "I'm sorry, but you don't have enough zeny.";
			close;
		}
		Zeny -= .heal_price;
		percentheal 100,100;
		break;
	
	case 2:
		if (Zeny < .buff_price) {
			mes "I'm sorry, but you don't have enough zeny.";
			close;
		}
		Zeny -= .buff_price;
		sc_start SC_BLESSING,300000,10;
		sc_start SC_INC_AGI,300000,10;
		break;
}
close;

OnInit:
.heal_price = 1000;
.buff_price = 5000;
end;
}

Now, there being put to use! But wait, if you look at the mes commands, they still say 1,000 and 5,000 in them. This isn't good, because if we change the values of our variables, those mes commands won't show the proper amount. And we don't want to type it out EACH and EVERY time we make changes. So let's edit that text. So go over to the line that tells players how much healing costs.
And were going to make the following changes:
mes "^FF0000 *Note - It costs "+ .heal_price +" zeny to get healed.* ^000000";

So, as your looking at this, you'll see the following was removed: 1,000 and the following was added in it's place: "+ .heal_price +" pay close attention to this, as it's very important. Take a close look at these: "+ and +" .
I'm going to go a bit into detail on why we need these in this spoiler. If you already know why we used them, continue on with the lesson.
Spoiler

Okay, now let's make the same changes to line where we tell players how much it costs to get buffed, but using the other variable this time:
mes "^FF0000 *Note - INCREASED AGI + BLESSING Level 10 costs "+ .buff_price +" zeny.* ^000000";

After that we are done! So, your script should look something like this:
prontera,150,180,4	script	Healer	4_F_ARUNA_POP,{
mes "[^0000FF Healer ^000000]";
mes "Would you like me to heal you?";
mes "^FF0000 *Note - It costs "+ .heal_price +" zeny to get healed.* ^000000";
mes "^FF0000 *Note - INCREASED AGI + BLESSING Level 10 costs "+ .buff_price +" zeny.* ^000000";
switch( select("Yes, heal me.", "I want buffs", "No thank you") ) {
	case 1:
		if (Zeny < .heal_price) {
			mes "I'm sorry, but you don't have enough zeny.";
			close;
		}
		Zeny -= .heal_price;
		percentheal 100,100;
		break;
	
	case 2:
		if (Zeny < .buff_price) {
			mes "I'm sorry, but you don't have enough zeny.";
			close;
		}
		Zeny -= .buff_price;
		sc_start SC_BLESSING,300000,10;
		sc_start SC_INC_AGI,300000,10;
		break;
}
close;

OnInit:
.heal_price = 1000;
.buff_price = 5000;
end;
}
Now, every time we want to change how much getting healed or buffed costs, we just change the values of those variables.]]> Tue, 25 Nov 2014 05:03:00 +0000 http://herc.ws/board/blog/29/entry-93-basic-healer-buffer-script/ Scripting Techniques, Tutorials and Guides http://herc.ws/board/blog/29/entry-92-scripting-techniques-tutorials-and-guides/ So in order to continue helping everyone learn how to script, I'm going to be slowly migrating the Tutorials and Guides from my Support Topic to this blog.
As a result, this will also allow me to organize it easier ( no more spoiler spamming ). And as always, I'll try my best to make continuous posts with new scripts, so as to expand your scripting knowledge even further.

Thank you for your patience and support :D]]> Tue, 25 Nov 2014 04:46:00 +0000 http://herc.ws/board/blog/29/entry-92-scripting-techniques-tutorials-and-guides/